Mẹo thông minh giúp sửa code Macro excel tiết kiệm thời gian

Trong lúc làm bài tập 2, em có một ý như thế này:

- Em cần chỉnh sửa code nhiều lần, chạy lại nhiều file để test thử. Nhưng do macro không cho phép undo. Những gì trên bảng tính excel đã thực hiện bằng câu lệnh VBA rồi thì không thể undo lại được. Không lẻ mỗi lần sửa lại phải thu lại ?
Vì vậy em đã Export file để lưu đoạn code đó, sau đó mở file mới và Import vào là OK. Sau đó chỉnh sửa vô tư.

Đăng nhập/Đăng ký mở rộng

Còn 1 cách nhanh hơn:
Trước khi chạy Macro Bạn nên copy Sheet goc ra nhiều sheet trên cùng file rồi mới chạy. Hỏng đâu xóa đó mà sheet goc vẫn còn.
Áp dụng cho các bài tập của lớp VBA: Sheet "YeuCauChung" nên giữ nguyên để người chấm kiểm tra Macro.P/s: Mình là Bạn của anh TranHoe, đang học ké với Anh nên biết được thông tin Lớp VBA. Các AE đừng trách nhé!

trunga.jsc gửi lúc 14/4/2014 11:49

                               
Đăng nhập/Đăng ký mở rộng

Còn 1 cách nhanh hơn:
Trước khi chạy Macro Bạn nên copy Sheet goc ra nhiều sheet trên cùn ...

Vâng, Copy sheet ra nhiều sheet mới là tất nhiên phải làm vì phải sửa nhiều lần. Chúng ta chỉ cần ấn CTRL và kéo giữ chuột sheet cần copy thì nội dung chép y nguyên.  
Export file thứ nhất để lưu trước khi mình sửa xem coi sau khi sửa đoạn lênh sẽ như thế nào, thứ 2 có thể chép qua file excel tùy ý. Ví dụ như đã có một file lưu macro trước đó, ta muốn thêm những macro muốn làm sau này, nối các macro lại ...
Thân ái.

Sau khi làm xong bài tập 3 (thì cũng tỉnh rượu luôn) thì em thấy có một cách để kiểm tra code , đó là dòng lệnh nào nghi ngờ thừa thì cứ cho nó thành anh "ghi chú", khi chạy thử nếu qua dòng lệnh đó mà vẫn đạt kết quả mong muốn thì có thể xóa nó đi. Không biết có sai ko, sai thì các bác chỉ thêm, vì em đang ong ong, hjhj.

Cám ơn đã chia sẻ.

Nhưng do macro không cho phép undo.

Why NOT ????
Who 's  telll you that ?????

J-walk có cho free thời xưa

The Undo example

[Visual Basic] 纯文本查看 复制代码

'Custom data type for undoing
    Type SaveRange
        Val As Variant
        Addr As String
    End Type
    
'   Stores info about current selection
    Public OldWorkbook As Workbook
    Public OldSheet As Worksheet
    Public OldSelection() As SaveRange


Sub ZeroRange()
'   Inserts zero into all selected cells

'   Abort if a range isn't selected
    If TypeName(Selection) <> "Range" Then Exit Sub
    
'   The next block of statements
'   Save the current values for undoing
    ReDim OldSelection(Selection.Count)
    Set OldWorkbook = ActiveWorkbook
    Set OldSheet = ActiveSheet
    i = 0
    For Each cell In Selection
        i = i + 1
        OldSelection(i).Addr = cell.Address
        OldSelection(i).Val = cell.Formula
    Next cell
            
'   Insert 0 into current selection
    Application.ScreenUpdating = False
    Selection.Value = 0
    
'   Specify the Undo Sub
    Application.OnUndo "Undo the ZeroRange macro", "UndoZero"
End Sub


Sub UndoZero()
'   Undoes the effect of the ZeroRange sub
    
'   Tell user if a problem occurs
    On Error GoTo Problem

    Application.ScreenUpdating = False
    
'   Make sure the correct workbook and sheet are active
    OldWorkbook.Activate
    OldSheet.Activate
    
'   Restore the saved information
    For i = 1 To UBound(OldSelection)
        Range(OldSelection(i).Addr).Formula = OldSelection(i).Val
    Next i
    Exit Sub

'   Error handler
Problem:
    MsgBox "Can't undo"
End Sub